複數和有理數
Julia 包含預定義的複數和有理數類型，並支援所有標準 數學運算和基本函數。 轉換和提升 的定義方式，讓任何預定義數字類型組合（不論是原始類型或複合類型）的運算都能如預期般運作。
複數
全域常數 im 與複數 i 繫結，代表 -1 的主平方根。（使用數學家的 i 或工程師的 j 當作這個全域常數已被否決，因為它們是很熱門的索引變數名稱。）由於 Julia 允許數字字面值 與識別碼並置作為係數，這個繫結足以提供複數的便利語法，類似傳統的數學符號
julia> 1+2im
1 + 2im你可以對複數執行所有標準的算術運算
julia> (1 + 2im)*(2 - 3im)
8 + 1im
julia> (1 + 2im)/(1 - 2im)
-0.6 + 0.8im
julia> (1 + 2im) + (1 - 2im)
2 + 0im
julia> (-3 + 2im) - (5 - 1im)
-8 + 3im
julia> (-1 + 2im)^2
-3 - 4im
julia> (-1 + 2im)^2.5
2.729624464784009 - 6.9606644595719im
julia> (-1 + 2im)^(1 + 1im)
-0.27910381075826657 + 0.08708053414102428im
julia> 3(2 - 5im)
6 - 15im
julia> 3(2 - 5im)^2
-63 - 60im
julia> 3(2 - 5im)^-1.0
0.20689655172413793 + 0.5172413793103449im提升機制確保不同類型的運算元組合運作正常
julia> 2(1 - 1im)
2 - 2im
julia> (2 + 3im) - 1
1 + 3im
julia> (1 + 2im) + 0.5
1.5 + 2.0im
julia> (2 + 3im) - 0.5im
2.0 + 2.5im
julia> 0.75(1 + 2im)
0.75 + 1.5im
julia> (2 + 3im) / 2
1.0 + 1.5im
julia> (1 - 3im) / (2 + 2im)
-0.5 - 1.0im
julia> 2im^2
-2 + 0im
julia> 1 + 3/4im
1.0 - 0.75im請注意，3/4im == 3/(4*im) == -(3/4*im)，因為字面係數比除法結合得更緊密。
提供用於處理複數值的標準函數
julia> z = 1 + 2im
1 + 2im
julia> real(1 + 2im) # real part of z
1
julia> imag(1 + 2im) # imaginary part of z
2
julia> conj(1 + 2im) # complex conjugate of z
1 - 2im
julia> abs(1 + 2im) # absolute value of z
2.23606797749979
julia> abs2(1 + 2im) # squared absolute value
5
julia> angle(1 + 2im) # phase angle in radians
1.1071487177940904與往常一樣，複數的絕對值 (abs) 是它與零的距離。 abs2 給出絕對值的平方，對於複數特別有用，因為它避免了取平方根。 angle 以弧度為單位返回相位角（也稱為自變數或arg 函數）。其他 基本函數 的完整範圍也定義為複數
julia> sqrt(1im)
0.7071067811865476 + 0.7071067811865475im
julia> sqrt(1 + 2im)
1.272019649514069 + 0.7861513777574233im
julia> cos(1 + 2im)
2.0327230070196656 - 3.0518977991517997im
julia> exp(1 + 2im)
-1.1312043837568135 + 2.4717266720048188im
julia> sinh(1 + 2im)
-0.4890562590412937 + 1.4031192506220405im請注意，數學函數通常在應用於實數時返回實數值，在應用於複數時返回複數值。例如，sqrt 在應用於 -1 與 -1 + 0im 時表現不同，即使 -1 == -1 + 0im
julia> sqrt(-1)
ERROR: DomainError with -1.0:
sqrt was called with a negative real argument but will only return a complex result if called with a complex argument. Try sqrt(Complex(x)).
Stacktrace:
[...]
julia> sqrt(-1 + 0im)
0.0 + 1.0im從變數建構複數時，字面數字係數表示法 不適用。相反地，必須明確寫出乘法
julia> a = 1; b = 2; a + b*im
1 + 2im但是，不 建議這樣做。相反地，使用更有效率的 complex 函數直接從其實部和虛部建構複數值
julia> a = 1; b = 2; complex(a, b)
1 + 2im此建構避免了乘法和加法運算。
Inf 和 NaN 會在複數的實部和虛部中傳播複數，如 特殊浮點值 區段中所述
julia> 1 + Inf*im
1.0 + Inf*im
julia> 1 + NaN*im
1.0 + NaN*im有理數
Julia 有有理數類型，用來表示整數的精確比率。有理數使用 // 算子建構
julia> 2//3
2//3如果一個有理數的分子和分母有公因數，它們會約分到最簡形式，使得分母為非負數
julia> 6//9
2//3
julia> -4//8
-1//2
julia> 5//-15
-1//3
julia> -4//-12
1//3整數比率的這種標準化形式是唯一的，因此有理數值的相等性可以透過檢查分子和分母是否相等來測試。有理數值的標準化分子和分母可以使用 numerator 和 denominator 函數萃取
julia> numerator(2//3)
2
julia> denominator(2//3)
3通常不需要直接比較分子和分母，因為標準的算術和比較運算已經定義給有理數值
julia> 2//3 == 6//9
true
julia> 2//3 == 9//27
false
julia> 3//7 < 1//2
true
julia> 3//4 > 2//3
true
julia> 2//4 + 1//6
2//3
julia> 5//12 - 1//4
1//6
julia> 5//8 * 3//12
5//32
julia> 6//5 / 10//7
21//25有理數可以輕鬆轉換成浮點數
julia> float(3//4)
0.75從有理數轉換成浮點數會遵循以下恆等式，適用於 a 和 b 的任何整數值，但 b == 0 和 a == 0 && b < 0 這兩個情況除外
julia> a = 1; b = 2;
julia> isequal(float(a//b), a/b)
true建構無限有理數值是可以接受的
julia> 5//0
1//0
julia> x = -3//0
-1//0
julia> typeof(x)
Rational{Int64}不過，嘗試建構 NaN 有理數值是無效的
julia> 0//0
ERROR: ArgumentError: invalid rational: zero(Int64)//zero(Int64)
Stacktrace:
[...]一如往常，提升系統讓與其他數字類型的互動變得毫不費力
julia> 3//5 + 1
8//5
julia> 3//5 - 0.5
0.09999999999999998
julia> 2//7 * (1 + 2im)
2//7 + 4//7*im
julia> 2//7 * (1.5 + 2im)
0.42857142857142855 + 0.5714285714285714im
julia> 3//2 / (1 + 2im)
3//10 - 3//5*im
julia> 1//2 + 2im
1//2 + 2//1*im
julia> 1 + 2//3im
1//1 - 2//3*im
julia> 0.5 == 1//2
true
julia> 0.33 == 1//3
false
julia> 0.33 < 1//3
true
julia> 1//3 - 0.33
0.0033333333333332993