TOML

TOML.jl 是 Julia 標準函式庫，用於剖析和撰寫 TOML v1.0 檔案。

剖析 TOML 資料

julia> using TOML

julia> data = """
           [database]
           server = "192.168.1.1"
           ports = [ 8001, 8001, 8002 ]
       """;

julia> TOML.parse(data)
Dict{String, Any} with 1 entry:
  "database" => Dict{String, Any}("server"=>"192.168.1.1", "ports"=>[8001, 8001…

若要剖析檔案，請使用 TOML.parsefile。如果檔案有語法錯誤，將擲回例外

julia> using TOML

julia> TOML.parse("""
           value = 0.0.0
       """)
ERROR: TOML Parser error:
none:1:16 error: failed to parse value
      value = 0.0.0
                 ^
[...]

剖析函式還有其他版本 (TOML.tryparse 和 [TOML.tryparsefile])，這些版本在剖析器錯誤時不會擲回例外，而是傳回包含資訊的 TOML.ParserError

julia> using TOML

julia> err = TOML.tryparse("""
           value = 0.0.0
       """);

julia> err.type
ErrGenericValueError::ErrorType = 14

julia> err.line
1

julia> err.column
16

將資料匯出到 TOML 檔案

函數 TOML.print 用於將資料列印（或序列化）成 TOML 格式。

julia> using TOML

julia> data = Dict(
          "names" => ["Julia", "Julio"],
          "age" => [10, 20],
       );

julia> TOML.print(data)
names = ["Julia", "Julio"]
age = [10, 20]

julia> fname = tempname();

julia> open(fname, "w") do io
           TOML.print(io, data)
       end

julia> TOML.parsefile(fname)
Dict{String, Any} with 2 entries:
  "names" => ["Julia", "Julio"]
  "age"   => [10, 20]

可以根據某個值對金鑰進行排序

julia> using TOML

julia> TOML.print(Dict(
       "abc"  => 1,
       "ab"   => 2,
       "abcd" => 3,
       ); sorted=true, by=length)
ab = 2
abc = 1
abcd = 3

對於自訂結構，傳遞一個將結構轉換成受支援類型的函數

julia> using TOML

julia> struct MyStruct
           a::Int
           b::String
       end

julia> TOML.print(Dict("foo" => MyStruct(5, "bar"))) do x
           x isa MyStruct && return [x.a, x.b]
           error("unhandled type $(typeof(x))")
       end
foo = [5, "bar"]

參考資料

parse(x::Union{AbstractString, IO})
parse(p::Parser, x::Union{AbstractString, IO})

parsefile(f::AbstractString)
parsefile(p::Parser, f::AbstractString)

tryparse(x::Union{AbstractString, IO})
tryparse(p::Parser, x::Union{AbstractString, IO})

tryparsefile(f::AbstractString)
tryparsefile(p::Parser, f::AbstractString)

print([to_toml::Function], io::IO [=stdout], data::AbstractDict; sorted=false, by=identity)

Parser()

ParserError